怎樣做一個激活Windows10的bat腳本？
我想你想問的這個腳本應該是利用KMS，是Key Management Service的簡稱，這個功能是在Windows Vista之后的產品中的一種新型產品激活機制，目的是為了Microsoft更好的遏制非法軟件授權行為(盜版)。
通過KMS進行激活的一般稱為VL版，即VOLUME授權版，一般不會單獨在零售市場進行發售，一般是直接向企業提供電子ISO映像進行批量授權安裝，基于對KMS原理研究成果，我們可以自行搭建KMS激活服務器，實現每180天一次的自動激活，使得系統一直保持激活狀態。
【KMS激活命令】以管理員身份運行CMD（命令提示符）
slmgr /upk
slmgr /ipk xxxxx-xxxxx-xxxxx-xxxxx-xxxxx ;這里需要填入流出的KMS
slmgr /skms kms.xspace.in ;對應的KMS服務器，很多高手搭建的第三方
slmgr /ato
給你找了個例子，復制保存成KMS.bat 試試吧，這個需要和你安裝的WIN版本配套才可以用。
歡迎您點擊我頭像關注我，獲得更多更有趣的信息~
@echo off&setlocal EnableDelayedExpansion&color 3e
title KMS_Activation for Windows 10 - (hnfeng)
echo ::::::::::::::::::::::::::::::::::::::::::::::::
echo :: 自動檢查 Win10 的版本，導入相應的 KMS 密鑰 ::
echo :: ::
echo :: 然后連接指定的 KMS 服務器激活 Win10 ::
echo :: ::
echo ::::::::::::::::::::::::::::::::::::::::::::::::
echo.&echo.
:: 如果激活失敗，可能是因為連不到KMS服務器了，
:: 你僅需修改下面的KMS服務器地址
set KMS_Sev=kms.landiannews.com
::set KMS_Sev=kms.xspace.in
::set KMS_Sev=zh.us.to
::set KMS_Sev=kms.shuax.com
::set KMS_Sev=skms.ddns.net
::======================= 以下內容無需更改 ======================
call :verchk
call :adminchk
set Core=TX9XD-98N7V-6WMQ6-BX7FG-H8Q99
set CoreCountrySpecific=PVMJN-6DFY6-9CCP6-7BKTT-D3WVR
set CoreN=3KHY7-WNT83-DGQKR-F7HPR-844BM
set CoreSingleLanguage=7HNRX-D7KGG-3K4RQ-4WPJ4-YTDFH
set Professional=W269N-WFGWX-YVC9B-4J6C9-T83GX
set ProfessionalN=MH37W-N47XK-V7XM9-C7227-GCQG9
set Enterprise=NPPR9-FWDCX-D2C8J-H872K-2YT43
set EnterpriseN=DPH2V-TTNVB-4X9Q3-TJR4H-KHJW4
set Education=NW6C2-QMPVW-D7KKK-3GKT6-VCFB2
set EducationN=2WH4N-8QGBV-H22JP-CT43Q-MDWWJ
set EnterpriseS=WNMTR-4C88C-JK8YV-HQ7T2-76DF9
set EnterpriseSN=2F77B-TNFGY-69QQF-B8YKP-D69TJ
for /f "tokens=3 delims= " %%i in ('reg QUERY "HKLM\SOFTWARE\Microsoft\Windows NT\CurrentVersion" /v "EditionID"') do set EditionID=%%i
if defined %EditionID% (
cscript //Nologo %windir%\system32\slmgr.vbs /ipk !%EditionID%!
cscript //Nologo %windir%\system32\slmgr.vbs /skms %KMS_Sev%
cscript //Nologo %windir%\system32\slmgr.vbs /ato
) else (
echo.&echo Not found DEFINED Key: "%EditionID%".
echo.
)
pause
exit
:verchk
ver | find "10.0." >nul 2>nul && (goto :EOF)
echo.&echo The current OS is NOT Windows 10.
echo.&pause
exit
:adminchk
reg query "HKU\S-1-5-19" >nul 2>nul || (
cls&echo.&echo Run as ADMINISTRATOR, Pls.
echo.&echo Press any key to exit.
echo.&pause>nul
exit)
goto :EOF